忘記密碼
 立即註冊
查看: 5878|回覆: 6

轉貼:DVD用seesaw來處理你覺得如何

  [複製鏈接]

317

主題

2584

回帖

315

積分

新手上路

myav實習生

舊站積分
873
舊站發表文章數
2151
 樓主| 發表於 2007-9-11 23:21:11 | 顯示全部樓層

轉貼:DVD用seesaw來處理你覺得如何

您的HTPC有沒有ffdshow?或者ZP/MPC/Theatertek任一個播放平台?
相信目前還有很多人在看DVD.這是一篇技術性文章關於DVD銳利化處理,較適合的對象:雙核心.如果您的CPU夠力可以跑一跑seesaw,保證有更柔順的畫質,更不毛燥的銳利化.


請先下載必要的軟體及濾鏡:
Avisynth 2.5/ZP,MPC,或Theatertek三者任一/ffdshow

MT.dll
MaskTools.dll
mt_masktools.dll

RepairSSE2.dll and RemoveGrainSSE2.dll or...
...RepairSSE3 and RemoveGrainSSE3.dll

ColorMatrix.dll
Fluxsmooth.dll
TIVTC.dll
WarpSharp.dll

下載網址:http://www.avsforum.com/avs-vb/showthread.php?t=719041



Go 開工吧:

1.ffdshow如何啟動seesaw,請叫出ffdshow然後將內容如下設定:


上圖文字解釋如下:
Codecs tab
Set Mpeg2 to Libmpeg2, and check "DVD decoding".
Set Avisynth to Avisynth, Raw video to All supported

Avisynth tab
YV12 checked,
Add FFdshow Video source checked,
3:2 Pulldown box: Apply Pulldown checked,
Check Buffer back/Ahead: 1, 15
* 將下面幾行紅字COPY請來貼到avisynth text box, 然後按套用*

SetMemoryMax(1024)
tfm(order=1,chroma=false)
tdecimate(chroma=false)
FluxSmoothT(3)
ColorMatrix(Mode="Rec.601->Rec.709",clamp=false,threads=2)
MT("SeeSaw(NRlimit=0, NRlimit2=5, Sstr=2.22, Szp=1, Slimit=9, Sdamplo=16, Spower=1, sootheT=95, SdampHi=39)",3)
WarpSharp(depth=20, threshold=20)
[/COLOR]

Subtitles tab, Unchecked
Uncheck "Decode closed captions"
Uncheck "Accept embedded subs"
Uncheck "Accept SSA, ASS, ASS2 Subtitle (experimental)
Vobsub subpage, uncheck Vobsub Enable.


2.新增一個文字文件(TXT檔)於C:\Program Files\AviSynth 2.5\plugins;
將下面一串紅肉粽(code)內容copy貼上後改副檔名為.avsi

#  SeeSaw v0.3e (02 Jan 2006)
#
#  (Full Name: "Denoiser-and-Sharpener-are-riding-the-SeeSaw" )
#
#  This function provides a (simple) implementation of the "crystality sharpen" principle.
#  In conjunction with a user-specified denoised clip, the aim is to enhance
#  weak detail, hopefully without oversharpening or creating jaggies on strong
#  detail, and produce a result that is temporally stable without detail shimmering,
#  while keeping everything within reasonable bitrate requirements.
#  This is done by intermixing source, denoised source and a modified sharpening process,
#  in a seesaw-like manner.
#
#  This version is considered alpha.  
#
#  Usage:
#
#  a = TheNoisySource
#  b = a.YourPreferredDenoising()
#  SeeSaw( a, b, [parameters] )
#
#  You're very much encouraged to feed your own custom denoised clip into SeeSaw.
#  If the "denoised" clip parameter is omitted, a simple "spatial pressdown" filter is used.
#
#
#  Fiddled together by Didée, for your pleasure.
#


# =======  Main function  =======

function SeeSaw( clip  clp, clip "denoised",
\               int   "NRlimit",int "NRlimit2",
\               float "Sstr",   int "Slimit", float "Spower", float "SdampLo", float "SdampHi", float "Szp",
\               float "bias",   int "Smode",    int "sootheT",  int "sootheS", float "ssx",     float "ssy")
{
ssx      = default( ssx,      1.0 )       # supersampling factor x  /  SeeSaw doesn't require supersampling urgently.
ssy      = default( ssy,      ssx )       # supersampling factor y  /  if at all, small values ~1.25 seem to be enough.
NRlimit  = default( NRlimit,    2 )       # absolute limit for pixel change by denoising
NRlimit2 = default( NRlimit2, NRlimit+1)  # limit for intermediate denoising
Sstr     = default( Sstr,     1.5 )       # Sharpening strength (don't touch this too much)
Slimit   = default( Slimit, NRlimit+2 )   # positive: absolute limit for pixel change by sharpening
                                          # negative: pixel's sharpening difference is reduced to diff=pow(diff,1/abs(limit))
Spower   = default( Spower,     4 )       # exponent for modified sharpener
Szp      = default( Szp,     16+2 )       # zero point - below: overdrive sharpening - above: reduced sharpening
SdampLo  = default( SdampLo, Spower+1 )   # reduces overdrive sharpening for very small changes
SdampHi  = default( SdampHi,   24 )       # further reduces sharpening for big sharpening changes. Try 15~30. "0" disables.
bias     = default( bias,      49 )       # bias towards detail ( >= 50 ) ,  or towards calm result ( < 50 )
Smode    = default( Smode,     ssx<1.35 ? 11 : ssx<1.51 ? 20 : 19 )
sootheT  = default( sootheT,  49 )        # 0=minimum, 100=maximum soothing of sharpener's temporal instableness.
                                          # (-100 .. -1 : will chain 2 instances of temporal soothing.)
sootheS  = default( sootheS,   0 )        # 0=minimum, 100=maximum smoothing of sharpener's spatial effect.

Szp   = Szp / pow(Sstr, 1.0/4.0) / pow( (ssx+ssy)/2.0, 1.0/2.0 )
SdampLo = SdampLo / pow(Sstr, 1.0/4.0) / pow( (ssx+ssy)/2.0, 1.0/2.0 )

ox=clp.width
oy=clp.height
xss = m4(ox*ssx)
yss = m4(oy*ssy)
NRL   = string( NRlimit  )
NRL2  = string( NRlimit2 )
NRLL  = string( int(round( NRlimit2 * 100.0/bias - 1.0 )) )
SLIM  = string( abs(Slimit) )
BIAS1 = string( bias )
BIAS2 = string( 100-bias )
#ZRP   = string( abs(Szp) )
#PWR   = string( abs(Spower) )
#DMP   = string( SdampLo )

denoised = defined(denoised) ? denoised : mt_lutxy(clp,clp.removegrain(4,-1),"x "+NRL+" + y < x "+NRL+" + x "+NRL+" - y > x "+NRL+" - y ? ?",chroma="copy first")

NRdiff = mt_makediff(clp,denoised,chroma="process")
tame   = mt_lutxy(clp,denoised,"x "+NRLL+" + y < x "+NRL2+" + x "+NRLL+" - y > x "+NRL2+" - x "+BIAS1+" * y "+BIAS2+" * + 100 / ? ?")
head   = tame.sharpen2(Sstr,Spower,Szp,SdampLo,SdampHi,4)
# head = head.mt_merge(tame,tame.prewitt(multiplier=1.0).mt_expand().removegrain(20))

(ssx==1.0 && ssy==1.0) ? repair(tame.sharpen2(Sstr,Spower,Szp,SdampLo,SdampHi,Smode),head,1,-1,-1)
\                     : repair(tame.lanczosresize(xss,yss).sharpen2(Sstr,Spower,Szp,SdampLo,SdampHi,Smode),head.bicubicresize(xss,yss,-.2,.6),1,-1,-1).lanczosresize(ox,oy)

SootheSS(last,tame,sootheT,sootheS)
sharpdiff= mt_makediff(tame,last)

(NRlimit==0) ? clp : \
mt_lutxy(clp,NRdiff, "y 128 "+NRL+" + > x "+NRL+" - y 128 "+NRL+" - < x "+NRL+" + x y 128 - - ? ?",chroma="process")

Slimit>=0 ? mt_lutxy(last,sharpdiff,"y 128 "+SLIM+" + > x "+SLIM+" - y 128 "+SLIM+" - < x "+SLIM+" + x y 128 - - ? ?",chroma="copy first")
\        : mt_lutxy(last,sharpdiff,"y 128 == x x y 128 - abs 1 "+SlIM+" / ^ y 128 - y 128 - abs / * - ?",chroma="copy first")

return( last )
}


# =======  Modified sharpening function  =======

function sharpen2(clip clp, float strength, int power, float zp, float lodmp, float hidmp, int rgmode)
{
STR  = string( strength )
PWR  = string( 1.0/float(power) )
ZRP  = string(    ZP    )
DMP  = string(   lodmp  )
HDMP = (hidmp==0) ? "1" : "1 x y - abs "+string(hidmp)+" / 4 ^ +"

mt_lutxy( clp, clp.RemoveGrain(rgmode,-1,-1), \
           "x y == x x x y - abs "+ZRP+" / "+PWR+" ^ "+ZRP+" * "+STR+" * x y - 2 ^ x y - 2 ^ "+DMP+" + / * x y - x y - abs / * "+HDMP+" / + ?",chroma="copy first")
return( last )
}


# =======  Soothe() function to stabilze sharpening  =======

function SootheSS(clip sharp, clip orig, int "sootheT", int "sootheS")
{
sootheT  = default(sootheT, 25 )
sootheS  = default(sootheS,  0 )
sootheT  = (sootheT > 100) ? 100 : (sootheT < -100) ? -100 : sootheT
sootheS  = (sootheS > 100) ? 100 : (sootheS < 0) ? 0 : sootheS
ST    = string( 100 - abs(sootheT))
SSPT  = string( 100 - abs(sootheS))

mt_makediff(orig,sharp)

(sootheS==0) ? last
\           : mt_lutxy( last, last.removegrain(20,-1,-1),
\             "x 128 - y 128 - * 0 < x 128 - 100 / "+SSPT+" * 128 + x 128 - abs y 128 - abs > x "+SSPT+" * y 100 "+SSPT+" - * + 100 / x ? ?", chroma="ignore")

(sootheT==0) ? last
\           : mt_lutxy( last, last.temporalsoften(1,255,0,32,2),
\           "x 128 - y 128 - * 0 < x 128 - 100 / "+ST+" * 128 + x 128 - abs y 128 - abs > x "+ST+" * y 100 "+ST+" - * + 100 / x ? ?", chroma="ignore")

(sootheT > -1) ? last
\             : mt_lutxy( last, last.temporalsoften(1,255,0,32,2),
\             "x 128 - y 128 - * 0 < x 128 - 100 / "+ST+" * 128 + x 128 - abs y 128 - abs > x "+ST+" * y 100 "+ST+" - * + 100 / x ? ?",chroma="ignore")

mt_makediff(orig,last)
# mergechroma(sharp)  #  not needed in SeeSaw
return( last )
}


# =======  MOD4-and-atleast-16 helper function  =======

function m4(float x) {x<16?16:int(round(x/4.0)*4)}
[/COLOR]

3.將下載來的11個東東,放跟2.同一個資料夾

MT.dll
MaskTools.dll
mt_masktools.dll

RepairSSE2.dll and RemoveGrainSSE2.dll or...
...RepairSSE3 and RemoveGrainSSE3.dll

ColorMatrix.dll
Fluxsmooth.dll
TIVTC.dll
WarpSharp.dll



祝努力能得到成功,有更優的畫質.如果我講的還是不清楚請看這裡的原始內容有圖文並茂的設定(轉載自avsforum)
http://www.avsforum.com/avs-vb/showthread.php?t=719041
我只能啟動LimitedSharpenFaster,seesaw完全是不戰而敗(939單核心被完封了)[xx(]
PS:上述設定有錯請指正,希望跟大家一起來討論.順便了解到底要多強的U才能讓BD/HD-DVD以seesaw來處理,算是賜給我一點小小的啟發.
我從不覺得自己懂得多,繼續學習中...全音域劇院系統達成

99

主題

7373

回帖

0

積分

新手上路

五星級會員

舊站積分
2176
舊站發表文章數
5172
發表於 2007-9-13 20:23:11 | 顯示全部樓層
給你拍拍手[;)]
可是我還是有看沒懂 [!9]

317

主題

2584

回帖

315

積分

新手上路

myav實習生

舊站積分
873
舊站發表文章數
2151
 樓主| 發表於 2007-9-14 00:44:58 | 顯示全部樓層
原發表者是 潛水艇
[B]給你拍拍手[;)]
可是我還是有看沒懂 [!9] [/B]

潛大如果看不懂我寫的請直接看avsforum上寫的(請參上面的連結),可能會瞭一些.seesaw的銳利化比Xsharpen等等的要更好,不會毛躁且更為細緻
我從不覺得自己懂得多,繼續學習中...全音域劇院系統達成

99

主題

7373

回帖

0

積分

新手上路

五星級會員

舊站積分
2176
舊站發表文章數
5172
發表於 2007-9-14 12:06:26 | 顯示全部樓層
原發表者是 G660606
[B]
潛大如果看不懂我寫的請直接看avsforum上寫的(請參上面的連結),可能會瞭一些.seesaw的銳利化比Xsharpen等等的要更好,不會毛躁且更為細緻 [/B]

abc更看不懂[]

56

主題

343

回帖

0

積分

新手上路

二星級會員

舊站積分
6
舊站發表文章數
210
發表於 2007-11-20 16:15:21 | 顯示全部樓層

不能配kmp嗎

配kmp不能用嗎?確定嗎?我想用kmp的人應該比較多吧,可以再造福一下大家嗎?

317

主題

2584

回帖

315

積分

新手上路

myav實習生

舊站積分
873
舊站發表文章數
2151
 樓主| 發表於 2007-11-20 16:30:57 | 顯示全部樓層

Re: 不能配kmp嗎

原發表者是 tolkien99
[B]配kmp不能用嗎?確定嗎?我想用kmp的人應該比較多吧,可以再造福一下大家嗎? [/B]

絕對可以配KMP的,KMP有"強制使用"的選項[/SIZE]
我從不覺得自己懂得多,繼續學習中...全音域劇院系統達成

56

主題

343

回帖

0

積分

新手上路

二星級會員

舊站積分
6
舊站發表文章數
210
發表於 2007-11-20 17:47:00 | 顯示全部樓層

有人願意試用一下嗎

有人有試過嗎?我是很想玩玩看,但我電腦能力不強,英文也不好,很慘,重點是dvd的畫質在電腦螢幕上看真的不夠好,只要放到全螢幕,dvd就像vcd一樣,看了真難受,能昇頻就太好了!但不知實際效果如何?
您需要登錄後才可以回帖 登錄 | 立即註冊

本版積分規則

Archiver|MyAV視聽商情網 test

GMT+8, 2026-11-21 09:31 , Processed in 0.039383 second(s), 34 queries .

Powered by MyAV!

快速回覆 返回頂部 返回列表